Fórmula genérica
=INT(end-start)&" days "&TEXT(end-start,"h"" hrs ""m"" mins """)
Resumo
Para calcular e exibir os dias, horas e minutos entre duas datas, você pode usar a função TEXT com uma pequena ajuda da função INT. No exemplo mostrado, a fórmula em D5 é:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins """)
Explicação
A maior parte do trabalho nesta fórmula é feita pela função TEXT, que aplica um formato de número personalizado para horas e minutos a um valor criado subtraindo a data de início da data de término.
TEXT(C5-B5,"h"" hrs ""m"" mins """)
Este é um exemplo de incorporação de texto em um formato de número personalizado, e esse texto deve ser circundado por um par extra de aspas duplas. Sem as aspas duplas extras, o formato de texto personalizado é semelhante a este:
h "hrs" m "min"
O valor para dias é calculado com a função INT, que simplesmente retorna a parte inteira da data de término menos a data de início:
INT(C5-B5) // get day value
Observação: embora você possa usar "d" em um formato de número personalizado para dias, o valor será redefinido para zero quando os dias forem maiores que 31.
Incluir segundos
Para incluir segundos, você pode estender o formato de número personalizado desta forma:
=INT(C5-B5)&" days "&TEXT(C5-B5,"h"" hrs ""m"" mins ""s"" secs""")
Total de dias, horas e minutos entre as datas
Para obter o total de dias, horas e minutos entre um conjunto de datas de início e término, você pode adaptar a fórmula usando SUMPRODUCT assim:
=INT(SUMPRODUCT(ends-starts))&" days "&TEXT(SUMPRODUCT(ends-starts),"h"" hrs ""m"" mins """)
onde "termina" representa o intervalo de datas de término e "começa" representa o intervalo de datas de início. No exemplo mostrado, D11 contém esta fórmula:
=INT(SUMPRODUCT(C5:C9-B5:B9))&" days "&TEXT(SUMPRODUCT(C5:C9-B5:B9),"h"" hrs ""m"" mins """)
