Resumo
Para calcular o imposto de renda total com base em vários grupos de impostos, você pode usar VLOOKUP e uma tabela de taxas estruturada conforme mostrado no exemplo. A fórmula em G5 é:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1)
onde "inc" (G4) e "taxas" (B5: D11) são intervalos nomeados e a coluna D é uma coluna auxiliar que calcula o imposto total acumulado em cada colchete.
Antecedentes e contexto
O sistema tributário dos EUA é "progressivo", o que significa que as pessoas com maior renda tributável pagam uma taxa de imposto federal mais alta. As taxas são avaliadas entre parênteses definidos por um limite superior e inferior. O montante da renda que se enquadra em uma determinada faixa é tributado à taxa correspondente a essa faixa. À medida que a renda tributável aumenta, a renda é tributada em mais faixas de impostos. Muitos contribuintes, portanto, pagam várias taxas diferentes.
No exemplo mostrado, os suportes e taxas fiscais são para registradores únicos nos Estados Unidos para o ano fiscal de 2019. A tabela abaixo mostra os cálculos manuais para uma renda tributável de $ 50.000:
| Suporte | Cálculo | Imposto |
|---|---|---|
| 10% | ($ 9.700 - $ 0) x 10% | $ 970,00 |
| 12% | ($ 39.475 - $ 9.700) x 12% | $ 3.573,00 |
| 22% | ($ 50.000- $ 39.475) x 22% | $ 2.315,50 |
| 24% | N / D | $ 0,00 |
| 32% | N / D | $ 0,00 |
| 35% | N / D | $ 0,00 |
| 37% | N / D | $ 0,00 |
O imposto total é, portanto, de $ 6.858,50. (exibido como 6.859 no exemplo mostrado).
Notas de configuração
1. Esta fórmula depende da função VLOOKUP no "modo de correspondência aproximada". Quando no modo de correspondência aproximada, VLOOKUP varre os valores de pesquisa em uma tabela (que deve ser classificada em ordem crescente) até que um valor mais alto seja encontrado. Em seguida, ele "dará um passo para trás" e retornará um valor da linha anterior. No caso de uma correspondência exata, VLOOKUP retornará resultados da linha correspondida.
2. Para que VLOOKUP recupere os valores fiscais cumulativos reais, eles foram adicionados à tabela como uma coluna auxiliar na coluna D. A fórmula em D6, copiada, é:
=((B6-B5)*C5)+D5
Em cada linha, esta fórmula aplica a taxa da linha acima à renda nessa faixa.
3. Para facilitar a leitura, são definidos os seguintes intervalos nomeados: "inc" (G4) e "taxas" (B5: D11).
Explicação
No G5, o primeiro VLOOKUP é configurado para recuperar o imposto cumulativo à taxa marginal com estas entradas:
- O valor de pesquisa é "inc" (G4)
- A tabela de pesquisa é "taxas" (B5: D11)
- O número da coluna é 3, imposto cumulativo
- O tipo de correspondência é 1 = correspondência aproximada
VLOOKUP(inc,rates,3,1) // returns 4,543
Com uma renda tributável de $ 50.000, VLOOKUP, no modo de correspondência aproximada, corresponde a 39.475 e retorna 4.543, o imposto total de até $ 39.475.
O segundo VLOOKUP calcula a receita restante a ser tributada:
(inc-VLOOKUP(inc,rates,1,1)) // returns 10,525
calculado assim:
(50.000-39.475) = 10.525
Finalmente, o terceiro VLOOKUP obtém a (topo) taxa marginal de imposto:
VLOOKUP(inc,rates,2,1) // returns 22%
Isso é multiplicado pela receita calculada na etapa anterior. A fórmula completa é resolvida assim:
=VLOOKUP(inc,rates,3,1)+(inc-VLOOKUP(inc,rates,1,1))*VLOOKUP(inc,rates,2,1) =4,543+(10525)*22% =6,859
Taxas marginais e efetivas
A célula G6 contém a taxa marginal superior, calculada com VLOOKUP:
=VLOOKUP(inc,rates,2,1) // returns 22%
A taxa de imposto efetiva no G7 é o imposto total dividido pelo lucro tributável:
=G5/inc // returns 13.7%
Nota: Encontrei essa fórmula no blog de Jeff Lenning na Excel University. É um ótimo exemplo de como VLOOKUP pode ser usado no modo de correspondência aproximada e também como VLOOKUP pode ser usado várias vezes na mesma fórmula.
