Como usar a função VLOOKUP do Excel -

Resumo

VLOOKUP é uma função do Excel para pesquisar dados em uma tabela organizada verticalmente. VLOOKUP suporta correspondência aproximada e exata e caracteres curinga (*?) Para correspondências parciais. Os valores de pesquisa devem aparecer na primeira coluna da tabela passada para VLOOKUP.

Objetivo

Pesquise um valor em uma tabela, combinando na primeira coluna

Valor de retorno

O valor correspondente de uma tabela.

Sintaxe

= VLOOKUP (valor, tabela, col_index, (range_lookup))

Argumentos

valor - o valor a procurar na primeira coluna de uma tabela.
table - a tabela da qual recuperar um valor.
col_index - a coluna na tabela da qual recuperar um valor.
range_lookup - (opcional) TRUE = correspondência aproximada (padrão). FALSE = correspondência exata.

Versão

Excel 2003

Notas de uso

VLOOKUP é uma função do Excel para obter dados de uma tabela organizada verticalmente. Os valores de pesquisa devem aparecer na primeira coluna da tabela passada para VLOOKUP. VLOOKUP suporta correspondência aproximada e exata e caracteres curinga (*?) Para correspondências parciais.

V é para vertical

O objetivo de PROCV é obter informações de uma tabela organizada da seguinte forma:

Usando o número do pedido na coluna B como um valor de pesquisa, VLOOKUP pode obter o ID do cliente, o valor, o nome e o estado de qualquer pedido. Por exemplo, para obter o nome do cliente para o pedido 1004, a fórmula é:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Para dados horizontais, você pode usar HLOOKUP, INDEX e MATCH ou XLOOKUP.

VLOOKUP é baseado em números de coluna

Ao usar PROCV, imagine que todas as colunas da tabela são numeradas, começando da esquerda. Para obter um valor de uma coluna específica, forneça o número apropriado como o "índice da coluna". Por exemplo, o índice da coluna para recuperar o primeiro nome abaixo é 2:

O sobrenome e o e-mail podem ser recuperados com as colunas 3 e 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address

PROCV só parece certo

PROCV só pode olhar para a direita. Os dados que você deseja recuperar (valores de resultado) podem aparecer em qualquer coluna à direita dos valores de pesquisa:

Se você precisar pesquisar valores à esquerda, consulte INDEX e MATCH ou XLOOKUP.

Correspondência exata e aproximada

VLOOKUP tem dois modos de correspondência, exata e aproximada. O nome do argumento que controla a correspondência é " range_lookup ". Este é um nome confuso, porque parece ter algo a ver com intervalos de células como A1: A10. Na verdade, a palavra "intervalo" neste caso se refere a "intervalo de valores" - quando range_lookup for TRUE, VLOOKUP corresponderá a um intervalo de valores em vez de um valor exato. Um bom exemplo disso é usar VLOOKUP para calcular notas.

É importante entender que range_lookup padrão é TRUE, o que significa que PROCV usará correspondência aproximada por padrão, o que pode ser perigoso. Defina range_lookup como FALSE para forçar a correspondência exata:

=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match

Nota: Você também pode fornecer zero (0) em vez de FALSE para uma correspondência exata.

Combinação exata

Na maioria dos casos, você provavelmente desejará usar VLOOKUP no modo de correspondência exata. Isso faz sentido quando você tem uma chave exclusiva para usar como um valor de pesquisa, por exemplo, o título do filme nestes dados:

A fórmula em H6 para encontrar o ano , com base em uma correspondência exata do título do filme, é:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Correspondência aproximada

In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.

Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.

First match

In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Wildcard match

The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Read a more detailed explanation here.

Two-way lookup

Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

For more details, see this example.

Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.

Multiple criteria

The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:

=C5&D5 // helper column

VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:

=VLOOKUP(H4&H5,B5:E13,4,0)

For details, see this example.

Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.

VLOOKUP and #N/A errors

If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:

One way to "trap" the NA error is to use the IFNA function like this:

The formula in H6 is:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:

The lookup value does not exist in the table
The lookup value is misspelled, or contains extra space
Match mode is exact, but should be approximate
The table range is not entered correctly
You are copying VLOOKUP, and the table reference is not locked

More about VLOOKUP

More VLOOKUP examples
VLOOKUP videos
23 tips for using VLOOKUP

Other notes

Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.